Voici un script de modification de configuration IP de Windows : adresse IP, masque de sous-réseau, passerelle par défaut, serveurs DNS. Il permet de choisir une configuration IP prédéfinie à partir d'un menu.

Ici, l'interface réseau à configurer s'appelle Intel wireless, mais le nom affecté par défaut par Windows est Connexion au réseau local, il faut donc adapter cette valeur au nom de l'interface réseau à configurer.
Il y a, dans cet exemple, 3 configurations différentes :

  • dhcp : adressage complet dynamique (client DHCP), typiquement pour une connexion publique
  • home : adressage complet fixe, typiquement pour une connexion domestique
  • p2p : adressage fixe partiel pour une connexion point à point, par un câble croisé par exemple.

Dans la configuration home, 192.168.1.2 est l'adresse du PC, 192.168.1.254 celle de la passerelle par défaut et 1 est le nombre de sauts (routeurs) vers la passerelle par défaut.

 @echo off
 set interface="Intel wireless"
 echo.
 echo %interface% IP configuration
 echo.
 echo d. DHCP
 echo f. Fixed (home config)
 echo p. Fixed (10.0.0.2)
 echo q. quit
 echo.
 choice /C:dfpq /N ?
 if errorlevel = 4 goto end
 if errorlevel = 3 goto p2p
 if errorlevel = 2 goto home
 if errorlevel = 1 goto dhcp
 goto end
 
 :dhcp
 netsh interface ip set address %interface% dhcp
 netsh interface ip set dns %interface% dhcp
 goto end
 
 :home
 netsh interface ip set address %interface% static 192.168.1.2 255.255.255.0 192.168.1.254 1
 netsh interface ip set dns %interface% static 192.168.1.254 primary
 rem netsh interface ip add dns %interface% 210.12.34.56 2
 goto end
 
 :p2p
 netsh interface ip set address %interface% static 10.0.0.2 255.255.255.0 none
 netsh interface ip set dns %interface% dhcp
 goto end
 
 :end

Ce script utilise le petit programme MS-DOS CHOICE.COM qui n'est plus inclu dans Windows XP.